cmake/librw-config.cmake.in


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34

include("${CMAKE_CURRENT_LIST_DIR}/librw-targets.cmake")

set(LIBRW_PLATFORM "@LIBRW_PLATFORM@")
set(LIBRW_PLATFORMS "@LIBRW_PLATFORMS@")
set(LIBRW_PLATFORM_@LIBRW_PLATFORM@ ON)

if(LIBRW_PLATFORM_GL3)
    set(LIBRW_GL3_GFXLIB "@LIBRW_GL3_GFXLIB@")
    set(LIBRW_GL3_GFXLIBS "@LIBRW_GL3_GFXLIBS@")

    set(OpenGL_GL_PREFERENCE GLVND)
    find_package(OpenGL)
    if(NOT TARGET OpenGL::OpenGL AND NOT TARGET OpenGL::EGL AND NOT TARGET OpenGL::GL)
        message(FATAL_ERROR "find_package(OpenGL) failed: no target was created")
    endif()

    include(CMakeFindDependencyMacro)
    if(LIBRW_GL3_GFXLIB STREQUAL "GLFW")
        if (NOT TARGET glfw)
            find_dependency(glfw3 REQUIRED)
        endif()
    elseif(LIBRW_GL3_GFXLIB STREQUAL "SDL2")
        if (NOT TARGET SDL2::SDL2)
            find_dependency(SDL2 CONFIG)
            if (NOT TARGET SDL2::SDL2)
                find_dependency(SDL2 MODULE REQUIRED)
            endif()
        endif()
    elseif(LIBRW_GL3_GFXLIB STREQUAL "SDL3")
        if (NOT TARGET SDL3::SDL3)
            find_dependency(SDL3 CONFIG REQUIRED)
        endif()
    endif()
endif()