Import aap/librw @ masterHEADmaster

Snapshot for re3/reVC vendoring, per @lzcnt.
Source: https://github.com/aap/librw (master).

1 files changed, 86 insertions, 0 deletions

diff --git a/skeleton/CMakeLists.txt b/skeleton/CMakeLists.txt
new file mode 100644
index 0000000..d6956be
--- /dev/null
+++ b/skeleton/CMakeLists.txt
@@ -0,0 +1,86 @@
+add_library(librw_skeleton
+    glfw.cpp
+    sdl2.cpp
+    sdl3.cpp
+    skeleton.cpp
+    skeleton.h
+    win.cpp
+
+    imgui/imgui_impl_rw.cpp
+    imgui/imgui_impl_rw.h
+
+    imgui/imconfig.h
+    imgui/imgui.cpp
+    imgui/imgui.h
+    imgui/imgui_demo.cpp
+    imgui/imgui_draw.cpp
+    imgui/imgui_internal.h
+    imgui/imgui_tables.cpp
+    imgui/imgui_widgets.cpp
+    imgui/imstb_rectpack.h
+    imgui/imstb_textedit.h
+    imgui/imstb_truetype.h
+
+    imgui/ImGuizmo.cpp
+    imgui/ImGuizmo.h
+)
+add_library(librw::skeleton ALIAS librw_skeleton)
+target_compile_features(librw_skeleton PUBLIC cxx_std_11)
+
+set_target_properties(librw_skeleton
+    PROPERTIES
+        PREFIX ""
+        EXPORT_NAME skeleton
+        CXX_STANDARD 11
+)
+
+target_link_libraries(librw_skeleton
+    PRIVATE
+        librw
+)
+
+if (LIBRW_GL3_GFXLIB MATCHES "SDL[23]")
+    target_compile_definitions(librw_skeleton PRIVATE SDL_MAIN_HANDLED)
+endif()
+
+target_include_directories(librw_skeleton
+    PUBLIC
+        $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
+        $<INSTALL_INTERFACE:${LIBRW_INSTALL_INCLUDEDIR}/skeleton>
+)
+
+if(LIBRW_INSTALL)
+    install(
+        FILES
+            skeleton.h
+        DESTINATION "${LIBRW_INSTALL_INCLUDEDIR}/skeleton"
+    )
+
+    install(
+        FILES
+            imgui/imconfig.h
+            imgui/imgui.h
+            imgui/imgui_impl_rw.h
+            imgui/imgui_internal.h
+            imgui/ImGuizmo.h
+            imgui/imstb_rectpack.h
+            imgui/imstb_textedit.h
+            imgui/imstb_truetype.h
+        DESTINATION "${LIBRW_INSTALL_INCLUDEDIR}/skeleton/imgui"
+    )
+
+    install(
+        FILES
+            imgui/LICENSE_imgui.txt
+            imgui/LICENSE_imguizmo.txt
+        DESTINATION "${CMAKE_INSTALL_DOCDIR}"
+    )
+
+    install(
+        TARGETS librw_skeleton
+        EXPORT librw-targets
+        RUNTIME DESTINATION "${CMAKE_INSTALL_BINDIR}"
+        LIBRARY DESTINATION "${CMAKE_INSTALL_LIBDIR}"
+        ARCHIVE DESTINATION "${CMAKE_INSTALL_LIBDIR}"
+    )
+endif()